• Left click, select Open, select Bot Browser
• The upper left side of this browser represents categories of methods. The upper right shows the methods in each of these categories.
• Select the method category category on the left side.

• Draw a box "morph":

  box: aRectangle
  	"Draw a morph to represent the rectangle"
  	| rm |
  	rm := RectangleMorph new.
  	rm bounds: aRectangle.
  	rm color: Color transparent.
  	rm setBorderWidth: 2 borderColor: Color blue.
  	rm openInWorld.
   

• A driver method for box:

  makeBox
   "Create a box 200 pixels on a side around the current position of the Bot"
  
  	| pica rectangle |
  	pica := Bot new.
  	rectangle := Rectangle center: pica center extent: 200@200.
  	pica box: rectangle.
   

• accept this new method for your category mymethods
  - Middle button or Right/Left click on the method definition and accept (s)

• In the Bot workspace window type: Bot new makeBox
• This creates a new Bot, sends it a makeBox message with no parameters.
• Middle button or Right/left click on this command and select Do it
• To Erase this box morph:
  • Right click in the middle of the box morph. This brings up a "halo" menu.
  • Select the "X" in the upper left corner. This should delete the box morph.

• follow: n borderOfBox: aRectangle
  	self box: aRectangle.
  	n timesRepeat:
  		[ (aRectangle containsPoint: (self positionIfGo: 30))
  			ifTrue: [ self go: 30.
  					  self turnLeft: 30 atRandom ]
  			ifFalse: [ self turnLeft: 1 ] ]
   

• accept this new definition. Middle button (Right/Left) click and accept (s)

| pica rectangle |
pica := Bot new.
rectangle := Rectangle center: pica center extent: 200@200.
pica follow: 1000 borderOfBox: rectangle.

• boxAndExit
  	| box room room2 exit |
  	box := Rectangle center: World center extent: 200@200.
  	room := RectangleMorph new.
  	room bounds: box.
  	room color: Color transparent.
  	room setBorderWidth: 2 borderColor: Color blue.
  	room openInWorld.
  	exit := Rectangle origin: (box topRight + (-2@25)) extent: 100@50.
  	room2 := RectangleMorph new.
  	room2 bounds: exit.
  	room2 color: Color transparent.
  	room2 setBorderWidth: 2 borderColor: Color black.
  	room2 openInWorld.
   

• Accept this method with middle button (right/left click).

• follow: n borderOfBox: aRectangle turnAngle: angle1 escapeAngle: angle2
  	n timesRepeat:
  		[ (aRectangle containsPoint: (self positionIfGo: 30))
  			ifTrue: [ self go: 30.
  					  self turnLeft: angle1 atRandom ]
  			ifFalse: [ self turnLeft: angle2 atRandom ] ]
  
    

• Accept the new method

•  go
      | rect |
      rect := Rectangle center: World center extent: 200@200.
      self follow: 1000 borderOfBox: rect turnAngle: 90 escapeAngle: 360.
  
    

• Accept this new method

• In the Bot workspace type: Bot new boxAndExit, DoIt.
• Bot new go Select just this line and DoIt/
  Just this line, otherwise you'll keep drawing Rectangle morphs.